RAP - Virtual Elements
Im Umfeld der Projektionen gibt es virtuelle Elemente, wir zeigen dir wie du sie nutzen und implementieren kannst, um dein RAP Objekt zu erweitern.
Inhaltsverzeichnis
Bereits in einem älteren Artikel sind wir auf virtuelle Elemente in CDS Views eingegangen. Heute stellen wir eine weitere Variante vor, die vor allem in Projektionen von RAP Objekten verwendet wird.
Definition
Die Elemente erhalten im CDS View ein eigenes Schlüsselwort und erhalten wieder die Annotation, um die implementierende Klasse anzugeben. Diese virtuellen Elemente können nur in der Projektionsschicht verwendet werden und führen bei einem View oder Standard Entität zu einem Fehler.
@ObjectModel.virtualElementCalculatedBy: 'ABAP:ZCL_BS_DEMO_CRAP_VE_EXIT'
virtual NumberOfPositions : abap.int4,
Klasse
Die Klasse wird wieder entsprechend mit dem Interface IF_SADL_EXIT_CALC_ELEMENT_READ implementiert. Dabei reicht es die Methode CALCULATE mit Inhalt zu befüllen. Die Beispiel-Implementierung der Methode könnte wie folgt aussehen:
LOOP AT it_requested_calc_elements INTO DATA(ld_virtual_field).
LOOP AT ct_calculated_data ASSIGNING FIELD-SYMBOL(<ls_calculated_data>).
DATA(ld_tabix) = sy-tabix.
ASSIGN COMPONENT ld_virtual_field OF STRUCTURE <ls_calculated_data> TO FIELD-SYMBOL(<ld_field>).
DATA(ls_original) = CORRESPONDING ZBS_C_RAPCInvoice( it_original_data[ ld_tabix ] ).
IF ls_original-Partner = '1000000002'.
<ld_field> = 999.
ELSE.
SELECT FROM zbs_dmo_position
FIELDS COUNT( * )
WHERE document = @ls_original-Document
INTO @<ld_field>.
ENDIF.
ENDLOOP.
ENDLOOP.
Die Methode loopt über die angeforderten Elemente und ergänzt dann die Inhalte, die angefordert wurden. Um unsere Informationen aus den Daten abzuleiten, weisen wir diese einer internen Variable zu. Da die Datentypen als ANY definiert wurden, müssen wir diesen Weg gehen, um die Elemente über ihre Namen anzusprechen. Am Ende setzen wir für einen bestimmten Partner die Anzahl auf 999 und für alle anderen Partner ermitteln wir die Anzahl der Positionen. Die Gesamtimplementierung würde dann wie folgt aussehen:
CLASS zcl_bs_demo_crap_ve_exit DEFINITION
PUBLIC
FINAL
CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES if_sadl_exit_calc_element_read.
ENDCLASS.
CLASS zcl_bs_demo_crap_ve_exit IMPLEMENTATION.
METHOD if_sadl_exit_calc_element_read~calculate.
LOOP AT it_requested_calc_elements INTO DATA(ld_virtual_field).
LOOP AT ct_calculated_data ASSIGNING FIELD-SYMBOL(<ls_calculated_data>).
DATA(ld_tabix) = sy-tabix.
ASSIGN COMPONENT ld_virtual_field OF STRUCTURE <ls_calculated_data> TO FIELD-SYMBOL(<ld_field>).
DATA(ls_original) = CORRESPONDING ZBS_C_RAPCInvoice( it_original_data[ ld_tabix ] ).
IF ls_original-Partner = '1000000002'.
<ld_field> = 999.
ELSE.
SELECT FROM zbs_dmo_position
FIELDS COUNT( * )
WHERE document = @ls_original-Document
INTO @<ld_field>.
ENDIF.
ENDLOOP.
ENDLOOP.
ENDMETHOD.
METHOD if_sadl_exit_calc_element_read~get_calculation_info.
ENDMETHOD.
ENDCLASS.
Verwendung
Innerhalb von RAP können damit zusätzliche Informationen an das Frontend gegeben werden, die im Datenmodell so nicht vorhanden sind. Für technische Festwerte könnten so lesbare Inhalte übergeben werden. Das Ergebnis des oben gezeigten Beispiels sieht wie folgt aus:
Fazit
Die aktuelle Variante haben wir wie immer in GitHub commited, sodass du die Änderungen und Beispiele nachvollziehen kannst. Virtuelle Elemente sind recht einfach implementiert, es sollten allerdings Informationen aus JOIN und Assoziation bevorzugt verwendet werden.
