
ABAP - IS COMPATIBLE
In diesem Artikel schauen wir uns das neue Statement IS COMPATIBLE in ABAP an und vergleichen verschiedene Use-Cases dafür.
Inhaltsverzeichnis
In diesem Artikel schauen wir uns ein neues Statement für die Sprache ABAP an und wie wir es in unseren täglichen Gebrauch integrieren können.
Einleitung
Mit dem neuesten Release 2611 wurden im ABAP Environment nicht nur neue Entwickler-Features ausgeliefert, sondern auch neue Statements, die wir in ABAP verwenden können. Eines dieser Statements ist das IS COMPATIBLE, welches wir verwenden können, um zu prüfen, ob ein Typ einem Zieltyp entspricht, und wir damit unterschiedlich umgehen oder auch unterschiedliche Logiken dazu auslösen können.
Vorbereitung
Da das neue Statement vor allem mit unterschiedlichen Datentypen arbeitet, legen wir einmal zwei verschiedene Strukturen an, die einmal Personen und einmal Unternehmen darstellen sollen. In einem dritten Beispiel arbeiten wir mit polymorphen Strukturen und legen dazu auch ein Beispiel an.
TYPES:
BEGIN OF person,
first_name TYPE string,
last_name TYPE string,
age TYPE i,
END OF person.
TYPES:
BEGIN OF company,
company_name TYPE string,
founded TYPE i,
END OF company.
TYPES polimorphic TYPE ANY STRUCTURE CONTAINING last_name TYPE string.
CASE
Der erste Fall ist das CASE-Statement, um die verschiedenen Datentypen auszusteuern und auch zuzuweisen. Dabei verwenden wir das Konstrukt CASE DATA TYPE OF und geben unsere übergebene Variable an. Im zweiten Schritt können wir in den WHEN-Statements dann vergleichen, ob die Variable einem bestimmten Typen entspricht. Hier können wir bereits Aktionen durchführen. Als weiteren Zusatz können wir aber auch das ASSIGNING verwenden, um dann die Variable direkt einem neuen Feldsymbol mit dem richtigen Datentyp zuzuweisen. Das Feld STRUCTURE hat den Datentyp ANY, so können wir von außen her jeden Datentyp übergeben. Anschließend können wir die Verarbeitung durchführen. In diesem Fall erzeugen wir einfach unterschiedliche Ausgaben in der Konsole, den unterschiedlichen Daten entsprechend.
CASE DATA TYPE OF structure.
WHEN COMPATIBLE WITH person ASSIGNING FIELD-SYMBOL(<person>).
out->write( |Name: { <person>-first_name }{ <person>-last_name }, Age: { <person>-age }| ).
WHEN COMPATIBLE WITH company ASSIGNING FIELD-SYMBOL(<company>).
out->write( |Name: { <company>-company_name }, Founded in: { <company>-founded }| ).
ENDCASE.
Abfrage
Als zweiten Zusatz können wir auch einen Vergleich in einem IF-Statement durchführen. So können wir unser übergebenes Feld, in diesem Fall ein einfacher Datentyp vom Typ ANY, mit einem Zieldatentyp vergleichen. Wir wollen wissen, ob es sich um einen Integer handelt. Wenn es sich um einen Integer handelt, machen wir eine Ausgabe mit dem Feld. Ansonsten geben wir an, dass es sich um ein falsches Ausgabeformat handelt, und konvertieren das Feld immer auf einen String, damit wir es auch in einen String schreiben können.
IF field IS COMPATIBLE WITH i.
out->write( |Magic number: { field }| ).
ELSE.
out->write( |Wrong output format: { CONV string( field ) }| ).
ENDIF.
Polymorphe Strukturen
Dazu noch ein letzter Test mit der polymorphen Struktur. Hier geben wir als Vergleichsreferenz im CASE-Statement unsere polymorphe Struktur an. Ist dies der Fall, casten wir auf diesen Datentyp. Dazu geben wir dann auch einen vorbereiteten String aus, wenn der Cast geklappt hat. Grundsätzlich funktionieren das Kompilieren und auch die Ausführung des Codes. Damit sind auch halbgenerische Strukturen mit dem neuen Statement möglich.
CASE DATA TYPE OF structure.
WHEN COMPATIBLE WITH polimorphic ASSIGNING FIELD-SYMBOL(<poly>).
out->write( |Last-Name of Person: { <poly>-last_name }| ).
WHEN OTHERS.
out->write( |Wrong structure| ).
ENDCASE.
Ausgabe
Zum Abschluss können wir unsere Testklasse auch noch einmal ausführen und sehen die verschiedenen Use Cases: von richtig übergebenen Datentypen, Datentypen, die gar nicht passen, und den Vergleichen, die wir im Code zur Verfügung haben. Im nächsten Abschnitt findest du den Testcode, wenn du es in deinem System einmal nachstellen möchtest oder verstehen willst, wie wir die Beispiele aufgebaut haben.
Vollständiges Beispiel
Das vollständige Beispiel findest du als ausführbare Klasse im nachfolgenden Abschnitt. Damit kannst du das Beispiel auf deinem System nachstellen und ausprobieren. Bitte beachte das aktuelle Release, welches dafür benötigt wird.
CLASS zcl_bs_demo_compatible DEFINITION
PUBLIC FINAL
CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES if_oo_adt_classrun.
TYPES:
BEGIN OF person,
first_name TYPE string,
last_name TYPE string,
age TYPE i,
END OF person.
TYPES:
BEGIN OF company,
company_name TYPE string,
founded TYPE i,
END OF company.
TYPES polimorphic TYPE ANY STRUCTURE CONTAINING last_name TYPE string.
PRIVATE SECTION.
METHODS output_format
IMPORTING !structure TYPE any
!out TYPE REF TO if_oo_adt_classrun_out.
METHODS output_number
IMPORTING !field TYPE any
!out TYPE REF TO if_oo_adt_classrun_out.
METHODS output_generic
IMPORTING !structure TYPE any
!out TYPE REF TO if_oo_adt_classrun_out.
ENDCLASS.
CLASS zcl_bs_demo_compatible IMPLEMENTATION.
METHOD if_oo_adt_classrun~main.
FINAL(person) = VALUE person( first_name = `John`
last_name = `Doe`
age = 20 ).
FINAL(company) = VALUE company( company_name = `Fruits and More`
founded = 1927 ).
output_format( structure = person
out = out ).
output_format( structure = company
out = out ).
FINAL(number) = 42.
FINAL(string) = `A longer sentence`.
FINAL(char) = 'FIXED'.
output_number( field = number
out = out ).
output_number( field = string
out = out ).
output_number( field = char
out = out ).
output_generic( structure = person
out = out ).
output_generic( structure = company
out = out ).
ENDMETHOD.
METHOD output_format.
CASE DATA TYPE OF structure.
WHEN COMPATIBLE WITH person ASSIGNING FIELD-SYMBOL(<person>).
out->write( |Name: { <person>-first_name }{ <person>-last_name }, Age: { <person>-age }| ).
WHEN COMPATIBLE WITH company ASSIGNING FIELD-SYMBOL(<company>).
out->write( |Name: { <company>-company_name }, Founded in: { <company>-founded }| ).
ENDCASE.
ENDMETHOD.
METHOD output_number.
IF field IS COMPATIBLE WITH i.
out->write( |Magic number: { field }| ).
ELSE.
out->write( |Wrong output format: { CONV string( field ) }| ).
ENDIF.
ENDMETHOD.
METHOD output_generic.
CASE DATA TYPE OF structure.
WHEN COMPATIBLE WITH polimorphic ASSIGNING FIELD-SYMBOL(<poly>).
out->write( |Last-Name of Person: { <poly>-last_name }| ).
WHEN OTHERS.
out->write( |Wrong structure| ).
ENDCASE.
ENDMETHOD.
ENDCLASS.
Fazit
Über das neue Statement können Datentypen recht schnell und einfach abgeglichen werden und verschiedene Logiken dazu implementiert werden, ohne eine komplexe Vorabanalyse durchzuführen. In Zukunft sollte das in einer generischen Verarbeitung etwas mehr Zeit und Quellcode sparen.
Weitere Informationen:
SAP Help - IS COMPATIBLE
SAP Help - CASE DATA TYPE
